Tool bar

The SCOadmin tool bar consists of a row of icons located below the menu bar. These icons can be configured to provide quick access to the most commonly-used menu selections.

``Template toolbar procedure: UiBuildToolBar'' illustrates how to do this:

• The pathnames for icons are loaded using the same mechanism used for localizing messages. In this instance, the global array appvals(toolbarIcons) is loaded with the path for each icon (open host, refresh, examine, and delete - standard icons located in /usr/lib/scoadmin/icons). Icons specific to a manager are located with the rest of the manager files in /usr/lib/scoadmin/manager.

• The point help for each icon is loaded into the array (appvals(toolbarCommands)).

• The default tool bar is loaded.

• SaToolbarLoad(3tlib) is used to load any user customizations for the toolbar into appvals(toolbarcust).

• SaToolbar(3tlib) is then used to construct the toolbar.

See also:

``Exiting the application''
• ``Localizing your manager''

• Template: uitoolbar.tcl

Template toolbar procedure: UiBuildToolBar

proc UiBuildToolBar {form top} {
	global appvals

	set client $appvals(client)
	set frame IN
	set visibility 1

	# relevant icons
	set appvals(toolbarIcons) [list \
		[IntlMsg TB_OPENHOST] \
		[IntlMsg TB_REFRESH] \
		[IntlMsg TB_EXAMINE] \
		[IntlMsg TB_DELETE] \
		]

	# set of toolbar command records: tag callback shorthelpstring
	set appvals(toolbarCommands) [list \
		[list openhost SaOpenHostCB \
			[IntlMsg OPENHOST_SH [list $appvals(itemname)]]] \
		[list refresh UiRefreshCB \
			[IntlMsg REFRESH_SH]] \
		[list examine UiExamineCB \
			[IntlMsg EXAMINE_SH]] \
		]

	# build the standard default toolbar
	set standard {}
	# open host turned on?
	if {$appvals(openhost)} {
		lappend standard {0 0}
		lappend standard {{} S}
	}
	lappend standard {1 1}
	lappend standard {2 2}
	set appvals(toolbarStandard) $standard

	set current $appvals(toolbarStandard)
	if {$appvals(toolbarcust)} {
		SaToolbarLoad $client visibility current frame
	} else {
		SaToolbarLoad $client visibility
	}	
	set toolbar \
		[SaToolbar 	$form.toolbar $top \
				$appvals(toolbarIcons) \
				$appvals(toolbarCommands) \
				$appvals(toolbarStandard) \
				SaShortHelpCB \
				$visibility \
				$current \
				$frame \
				UiToolBarResensitizeCB \
				UiToolBarCustomizeCB \
				]
	VxSetVar $appvals(vtMain) toolbar $toolbar
	return $toolbar
}